RE: 85xx <------> 65xx Mutually replaceable?

From: Gideon Zweijtzer (gideonz_at_dds.nl)
Date: 2003-07-07 19:29:36

-- Sorry for posting this to CBM Hackers.. The reason is that my
mistakes can be esaily tracked down and corrected by you guys before
Mario tries it --


Hoi Mario,

I think it should be something like this:

100 POKE 56334,PEEK(56334)AND254: REM SWITCH OFF INTERRUPTS
110 POKE 1,51: REM ENABLE READING CHAR ROM
120 FOR I=0 to 2047:POKE 8192+I,PEEK(53248+I):NEXT:REM $2000
130 FOR I=0 to 2047:POKE 24576+I,PEEK(55296+I):NEXT:REM $6000
140 FOR I=0 to 2047:POKE 40960+I,PEEK(53248+I):NEXT:REM $A000
150 FOR I=0 to 2047:POKE 57344+I,PEEK(55296+I):NEXT:REM $E000
160 POKE 1,55: REM RE-ENABLE I/O CHIPS
170 POKE 56334,PEEK(56334)OR1: REM TURN INTERRUPTS BACK ON
180 POKE 53272,(PEEK(53272)AND240)OR 8: REM SWITCH TO $2000
190 PRINT "TRYING BANK 0"
200 POKE 56576,(PEEK(56576)AND252)OR 3: REM BANK 0
210 FOR I=0 TO 10000:NEXT
220 PRINT "TRYING BANK 1"
230 POKE 56576,(PEEK(56576)AND252)OR 2: REM BANK 1
240 FOR I=0 TO 10000:NEXT
250 PRINT "TRYING BANK 2"
260 POKE 56576,(PEEK(56576)AND252)OR 1: REM BANK 2
270 FOR I=0 TO 10000:NEXT
280 PRINT "TRYING BANK 3"
290 POKE 56576,(PEEK(56576)AND252)OR 0: REM BANK 3
300 FOR I=0 TO 10000:NEXT
310 POKE 56576,(PEEK(56576)AND252)OR 3: REM BANK 0
320 POKE 53272,(PEEk(53272)AND240)OR 4: REM SWITCH BACK TO $1000
330 PRINT "THINGS SHOULD BE NORMAL NOW"

Of course the "trying bank n" messages won't appear if the banks switch
correctly, since the screen pointer is also moved up in steps of $4000.
But if the CharRom is still okay, you should see the characters
appearing now. In bank 0 I put the upper case chars, in bank 1, lower
case, etc... So you can really see the difference between the banks. Run
the program and let me know what you see... (After fixing the syntax
errors, please!)

The idea of running it from tape is a good one.

Gideon
 
> 
> Shalom Gideon,
> 
> 
> this could be done easier than it would seem. I just have to 
> type the thing on one of my breadboxen, save it on tape and 
> then just load the program on the C-64c, and even that I 
> could do by pressing shift+run/stop. Easy. But would be you 
> so kind and provide me with the code itself?
> 
> 
> Lehitraot
> 
> 
> mario
> 
> 
> ¤-----Original Message-----
> ¤From: ext Gideon Zweijtzer [mailto:gideonz@dds.nl]
> ¤Sent: 06 July 2003 20:19
> ¤To: cbm-hackers@cling.gu.se
> ¤Subject: RE: 85xx <------> 65xx Mutually replaceable?
> ¤
> ¤the bad guy can be found easily. Antoher method is, when you 
> can still ¤type (blindly) is to type a small program to copy 
> the character ROM to ¤RAM, and switch the VIC-II to retrieve 
> the characters from there. (The ¤addresspath from the VIC-II 
> to the ROM is different from the path used ¤by the CPU to the 
> ROM!). You could try this in different banks. With ¤some 
> logic reasoning, you'll find out where it goes wrong. 
> ¤This is how I
> ¤found out once that the 74LS373 latch was broken.
> ¤
> ¤Gideon
> ¤
> ¤
> ¤       Message was sent through the cbm-hackers mailing list
> ¤
> 



       Message was sent through the cbm-hackers mailing list

Archive generated by hypermail pre-2.1.8.